osmo-st-network/osmo/OsmoAppConnection.st

"
 (C) 2011-2013 by Holger Hans Peter Freyther
 All Rights Reserved

 This program is free software: you can redistribute it and/or modify
 it under the terms of the GNU Affero General Public License as
 published by the Free Software Foundation, either version 3 of the
 License, or (at your option) any later version.

 This program is distributed in the hope that it will be useful,
 but WITHOUT ANY WARRANTY; without even the implied warranty of
 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 GNU Affero General Public License for more details.

 You should have received a copy of the GNU Affero General Public License
 along with this program.  If not, see <http://www.gnu.org/licenses/>.
"

Object subclass: OsmoAppConnection [
    | socket writeQueue demuxer muxer dispatcher token hostname port
        tx_proc rx_proc started connect_block |
    <category: 'OsmoNetwork-Socket'>
    <comment: 'I connect to a OpenBSC App on the Control Port and wait for
TRAPS coming from the server and will act on these.
TODO: re-use the IPADispatcher across connections.'>

    OsmoAppConnection class >> connectionException [
        <category: 'exceptions'>
        ^ SystemExceptions.FileError
    ]

    OsmoAppConnection class >> new [
        ^(self basicNew)
            hostname: '127.0.0.1';
            port: 4250;
            yourself
    ]

    driveDispatch [
        <category: 'private'>

        [
            self dispatchOne
        ] on: SystemExceptions.EndOfStream do: [:e |
            self logError: 'OsmoApplication eof' area: #osmo.
            self scheduleReconnect
        ] on: SystemExceptions.FileError do: [:e |
            self logError: 'OsmoApplication file-error' area: #osmo.
            self scheduleReconnect
        ] on: Error do:  [:e |
            e logException: 'OsmoApplication error' area: #osmo.
            self scheduleReconnect
        ]
    ]

    driveSend [
        <category: 'private'>
        [
            self sendOne
        ] on: SystemExceptions.EndOfStream do: [:e |
            self logError: 'OsmoApplication eof' area: #osmo.
            self scheduleReconnect
        ] on: Error do:  [:e |
            e logException: 'OsmoApplication error' area: #osmo.
            self scheduleReconnect
        ]
    ]

    reconnect [
        <category: 'private'>
        self logNotice: 'Going to reconnect socket' area: #osmo.
        self terminate.
        started ifTrue: [self start]
    ]

    scheduleReconnect [
        <category: 'private'>
        socket ifNotNil: [socket close. socket := nil].
        TimerScheduler instance scheduleInSeconds: 1 block: [self reconnect].
        "We are done now"
        Processor activeProcess terminate
    ]


    initializeDispatcher [
        | ipa |
        "Allow another class to register handlers"
        dispatcher := IPADispatcher new.
        dispatcher initialize.
        connect_block ifNotNil: [connect_block value: dispatcher].
        ipa := (IPAProtoHandler new)
                    registerOn: dispatcher;
                    muxer: muxer;
                    token: token;
                    yourself
    ]

    nextPut: aData [
        muxer nextPut: aData with: IPAConstants protocolOsmoCTRL
    ]

    nextPut: aData with: aConstant [
        muxer nextPut: aData with: aConstant
    ]

    token: aToken [
        token := aToken.
    ]

    hostname: aHostname [
        <category: 'creation'>
        hostname := aHostname
    ]

    port: aPort [
        <category: 'creation'>
        port := aPort
    ]

    onConnect: aBlock [
        <category: 'creation'>
        "Call the block when the socket is being connected and the dispatcher
        is set-up. The callback will have the dispatcher as parameter."
        connect_block := aBlock.
    ]

    createConnection: aHostname port: aPort [
        <category: 'socket'>
        ^ Sockets.Socket remote: aHostname port: aPort.
    ]

    connect [
        <category: 'connect'>
        socket ifNotNil: [socket close].
        socket := self createConnection: hostname port: port.
        writeQueue := SharedQueue new.
        demuxer := IPADemuxer initOn: socket.
        muxer := IPAMuxer initOn: writeQueue.
        self initializeDispatcher.
    ]

    start [
        <category: 'connect'>
        started := true.

        [
            self logNotice: 'Attempting to connect' area: #osmo.
            self connect
        ] on: self class connectionException do: [
            self logError: 'Failed to connect.' area: #osmo.
            ^Osmo.TimerScheduler instance scheduleInSeconds: 1 block: [self reconnect]].

        rx_proc :=
            [Processor activeProcess name: 'OsmoAppConnection-RX'.
            [self driveDispatch] repeat] fork.
        tx_proc := [Processor activeProcess name: 'OsmoAppConnection-TX'.
            [self driveSend] repeat] fork
    ]

    stop [
        <category: 'connect'>
        started := false.
        self terminate
        "A reconnect timer might be running right now"
    ]

    terminate [
        <category: 'connect'>
        tx_proc ifNotNil: [tx_proc terminate].
        rx_proc ifNotNil: [rx_proc terminate].
        socket ifNotNil: [socket close. socket := nil]
    ]


    sendOne [
        | msg |
        <category: 'dispatch'>

        msg := writeQueue next.
        socket nextPutAllFlush: msg.
    ]

    dispatchOne [
        | msg |
        <category: 'dispatch'>

        msg := demuxer next.
        dispatcher dispatch: msg first with: msg second.
    ]
]